匯編數顯大型十字路口交通燈設計（proteus仿真加源代碼）

ID:253385 · 發表于 2017-11-25 12:49

這是一個交通十字路口的匯編程序的proteus仿真，十字每個路口有3個紅綠燈和一個人行燈。
仿真原理圖如下（proteus仿真工程文件可到本帖附件中下載）

匯編數顯大型交通燈控制單片機源程序如下:

;------------------------------------
;程序實現功能
;西南北路口直行與轉彎交替通行，數碼管顯示直行通行倒計時，紅綠黃燈顯示包括人行道在內的道路交通狀態。
;某一方向道路擁擠時，可以人工控制調節東西南北方向通行時間。
;緊急情況時，各路口交通燈顯示紅燈，數碼管保持數據不變。
;工作寄存器及存儲單元分配
;1.工作寄存器
;R2設置為定時器定時中斷次數,R6、R7用于延時程序中的寄存器
;2.片內存儲單元
;30H、31H作為兩組數碼管顯示數據存儲單元;32H、33H作為交通燈初始狀態存儲單元;40H、41H作為交通燈顯示數據存儲單元
;3.標志位
;00H：南北通行標志位 ; 01H：東西通行標志位;02H：緊急事件標志位
;-----------------------------------
SNF EQU 00H ;;;南北通行標志位
EWF EQU 01H ;;;東西通行標志位
URF EQU 02H ;;;緊急事件標志位
ORG 0000H
LJMP MAIN ;;;上電轉主程序
ORG 000BH ;;;定時中斷入口
LJMP DSZD
ORG 0003H ;;;緊急中斷入口
LJMP URZD
ORG 0030H
MAIN: LCALL INIT ;;;調用初始化子程序
LOOP: LCALL DIS ;;;循環執行顯示子程序
AJMP LOOP
;///////////初始化程序
INIT: SETB SNF
SETB EWF
SETB URF
MOV R2,#20 ;;;定時器中斷20次為1s
MOV TMOD,#01H ;;;初始化定時器
MOV TL0,#0B0H
MOV TH0,#3CH
SETB EA ;;;開定時中斷與緊急中斷
SETB ET0
SETB TR0
SETB EX0
SETB IT0 ;;;設置中斷程控方式
MOV DPTR,#TAB ;;;數值首地址放入DPTR中
MOV 40H,#40 ;;;東南西北通行時間設置
MOV 41H,#40
MOV 30H,#40 ;;;通行時間初始化
MOV 31H,#60
MOV P0,#4CH ;;;初始化時南北通行并把交通燈狀態分別放在32H和33H中
MOV 32H,#4CH
MOV P2,#15H
MOV 33H,#15H
RET
;////////////顯示子程序
DIS: MOV P3,#0DFH ;;;選中南北方向的十位數碼管
MOV A,30H ;;;把顯示數據送人數碼管顯示
MOV B,#10
DIV AB
MOVC A,@A+DPTR
MOV P1,A ;;;
LCALL D1MS
MOV P3,#0EFH ;;;選中南北方向的個位數碼管
MOV A,B ;;;送入數碼管顯示
MOVC A,@A+DPTR
MOV P1,A
LCALL D1MS
MOV P3,#7FH ;;;選中第東西方向的十位數碼管
MOV A,31H ;;;送入數碼管顯示
MOV B,#10
DIV AB
MOVC A,@A+DPTR
MOV P1,A
LCALL D1MS
MOV P3,#0BFH ;;;選中第東西方向的個位數碼管
MOV A,B
MOVC A,@A+DPTR
MOV P1,A
LCALL D1MS
SETB P3.0
SETB P3.1
JNB P3.0,DIS_S ;;;查詢是否第一個按鍵按下
JNB P3.1,DIS_E ;;;查詢是否第二個按鍵按下
AJMP DIS_R ;;;沒有鍵按下則返回
DIS_S:LCALL D5MS ;;;按鍵去抖
JNB P3.0,DIS_SN
AJMP DIS_R
DIS_SN:MOV 40H,#50 ;;;對通行時間從新分配，南北通行時間加長
MOV 41H,#30
AJMP DIS_R
DIS_E:LCALL D5MS ;;;按鍵去抖
JNB P3.1,DIS_EW
AJMP DIS_R
DIS_EW:MOV 40H,#30 ;;;東西通行時間加長
MOV 41H,#50
DIS_R:RET
;///////定時中斷處理程序
DS_C: LJMP DS_R ;;;接力跳轉
DSZD: PUSH ACC ;;;保護現場
PUSH PSW
CLR TR0 ;;;關定時器及中斷標志位并重新賦值
CLR TF0
MOV TL0,#0B0H
MOV TH0,#3CH
DJNZ R2,DS_C ;;;判斷1m時間是否到達
MOV R2,#20 ;;;到達重新賦值
DEC 30H ;;;南北方向通行時間減一
MOV A,30H ;;;把減一后的時間送入顯示存儲單元
;;;;;;;南北通行到達最后4秒時黃燈閃爍
DS_10:CJNE A,#4,DS_11 ;;;如果通行時間剩余4秒
JNB SNF,DS_11 ;;;判斷是否是南北通行
MOV P0,#8AH
MOV 32H, #8AH ;;;把交通燈狀態存入存儲單元（后面類似）
DS_11:CJNE A,#3,DS_12 ;;;不是剩余3秒，返回
JNB SNF,DS_12 ;;;不是南北通行時間，返回
MOV P0,#88H
MOV 32H, #88H
DS_12:CJNE A,#2,DS_13
JNB SNF,DS_13
MOV P0,#8AH
MOV 32H, #8AH
DS_13:CJNE A,#1,DS_14
JNB SNF,DS_14
MOV P0,#88H
MOV 32H, #88H
;------------------------
DS_14:JNZ DS_NE ;;;通行時間沒有結束轉向改變東西方向的數碼管
CPL SNF ;;;如果通行時間結束則對標志位取反
JNB SNF,DS_1 ;;;判斷是否南北通行
MOV 30H,40H ;;;是，點亮相應的交通燈
MOV P0,#4CH
MOV 32H,#4CH ;;;存儲交通燈狀態
MOV P2,#15H
MOV 33H, #15H ;;;存儲交通燈狀態
DS_NE:DEC 31H ;;;東西方向通行時間減一
MOV A,31H ;;;把通行剩余時間送入顯示存儲單元
;;;;;;;;東西方向通行時間剩余4秒鐘黃燈閃爍（程序注釋與南北方向類似略）
DS_20:CJNE A,#4,DS_21
JB EWF,DS_21
MOV P0,#51H
MOV 32H, #51H
DS_21:CJNE A,#3,DS_22
JB EWF,DS_22
MOV P0,#41H
MOV 32H, #41H
DS_22:CJNE A,#2,DS_23
JB EWF,DS_23
MOV P0,#51H
MOV 32H, #51H
DS_23:CJNE A,#1,DS_24
JB EWF,DS_24
MOV P0,#41H
MOV 32H, #41H
;-----------------------------
DS_24:JNZ DS_R ;;;東西方向時間沒有結束，返回
CPL EWF ;;;對通行狀態取反
JNB EWF,DS_2 ;;;東西方向通行時間到來，跳轉
MOV 31H,#80 ;;;東西方向通行結束，重新顯示時間
MOV P0,#89H ;;;點亮相應的交通燈
MOV 32H, #89H
MOV P2,#29H
MOV 33H, #29H
AJMP DS_R
DS_1: MOV 30H,#80 ;;;南北通行時間結束，重新對顯示存儲單元賦值
MOV P0,#89H ;;;執行轉彎狀態1
MOV 32H, #89H
MOV P2,#26H
MOV 33H, #26H
AJMP DS_NE
DS_2: MOV 31H,41H ;;;東西方向開始通行，賦值予顯示存儲單元
MOV P0,#61H ;;;點亮相應的交通燈
MOV 32H, #61H
MOV P2,#15H
MOV 33H, #15H
DS_R: SETB TR0
POP PSW ;;;恢復現場
POP ACC
RETI
;/////////////緊急中斷處理程序
URZD: PUSH ACC ;;;保護現場
PUSH PSW
CLR IE0 ;;;清除中斷標志位
CLR TR0 ;;;關定時器
CPL URF ;;;緊急事件標志位
JB URF,UR_CON ;;;緊急結束；跳轉
MOV P0,#49H ;;;各路口燈全顯示紅燈亮
……………………
…………限于本文篇幅余下代碼請從51黑下載附件…………

復制代碼

所有資料51hei提供下載:

交通燈.7z (28.76 KB, 下載次數: 314)

ID:347762 · 發表于 2018-6-8 17:39

有幫助

ID:348183 · 發表于 2018-6-9 14:14

做畢設，很有幫助

ID:348533 · 發表于 2018-6-10 10:41

南北和東西方向時間好像不能人工調節，怎么破？

ID:367247 · 發表于 2018-7-8 12:01

非常有用畢設專用

ID:394455 · 發表于 2018-9-6 11:03

很好，寫到很好

ID:420804 · 發表于 2018-11-5 00:33

很棒！

ID:424066 · 發表于 2018-11-11 01:45

為什么顯示connt open？是我打開的路徑不對嗎

ID:438875 · 發表于 2018-12-5 18:10

絕世好貼

ID:454759 · 發表于 2018-12-25 19:22

有幫助

ID:451964 · 發表于 2018-12-26 11:14

絕世好帖

ID:456275 · 發表于 2018-12-31 16:36

感謝樓主的分享，非常的有用

ID:545572 · 發表于 2019-5-23 14:23

很棒啊

ID:502774 · 發表于 2019-5-23 21:52

好帖。謝謝分享

ID:558890 · 發表于 2019-6-10 13:25

蟹蟹分享，找了好久了

ID:584044 · 發表于 2019-7-14 20:25

特別的好

ID:508556 · 發表于 2019-7-15 01:24

好好學習

ID:658814 · 發表于 2019-12-8 14:32

太棒了謝謝樓主

ID:658814 · 發表于 2019-12-8 14:33

贊，特別好用

ID:410072 · 發表于 2019-12-9 09:53

值得學習值得學習

ID:461651 · 發表于 2019-12-25 22:56

謝謝，值得學習參考

ID:678072 · 發表于 2019-12-31 18:12

請問有c語言代碼嗎？

ID:775719 · 發表于 2020-6-11 00:53

太贊了

ID:791132 · 發表于 2020-6-27 17:31

很有用！

ID:476962 · 發表于 2020-10-24 18:10

試試看看能不能用

帳號		自動登錄	找回密碼
密碼			立即注冊

wwwxxx国产_337p日本欧洲亚洲大胆张筱雨_免费在线看成人av_日本黄色不卡视频_国产精品成熟老女人_99视频一区_亚洲精品97久久中文字幕_免费精品视频在线_亚洲色图欧美视频_欧美一区二三区

匯編數顯大型十字路口交通燈設計（proteus仿真加源代碼）

評分

	沙發無效樓層，該帖已經被刪除

	11^# 無效樓層，該帖已經被刪除

	14^# 無效樓層，該帖已經被刪除