DHT11溫濕度模塊+LCD1602模塊制作顯示溫度溫度器

[復制鏈接]

電梯直達

樓主

ID:675619 發表于 2020-2-3 16:15 | 只看該作者 |只看大圖回帖獎勵

|倒序瀏覽 |閱讀模式

對于Arduino我也是個初學者，今天學個如何使用DHT11溫濕度模塊和LCD1602顯示模塊來制作一個溫度濕度儀器。
搜索了很多的相關資料，包括DHT11模塊的類庫和原理圖，和LCD1602的接線和原理圖等資料，終于搞定了這個實驗制作。
DHT11的類庫會作為附件提供

1、DHT11的連接線路比較簡單，在數據信號引腳（2腳）上要接個上拉電阻，阻值根據文檔要求是4.7kΩ，其他沒有特別需要注意的。

2、LCD1602的連接線路有點復雜，需要注意的是V0（3腳）可以接一個4.7kΩ的電阻，可以增加LCD1602的對比度，這個阻值可以根據自己的1602顯示效果來調整的，并不一定是4.7k。另外注意的是第15腳是1602的LED背光的正極，需要接一個100-200Ω左右的電阻，以調節背光的明暗度。

LCD1602默認是英文顯示，如果想要用中文顯示“溫度”“溫度”的，就要建立字庫，對于我這個初學者來說，就不要太復雜了，先用簡單的方式來做，有必要再進一步研究。

實驗所用到的材料有：
Arduino Uno，面包板，電阻（200Ω*1，4.7kΩ*2），DHT11模塊，LCD1602模塊，杜邦線等

連接示意圖

原理圖

源代碼

double Fahrenheit(double celsius)
{
return 1.8 * celsius + 32;
} //攝氏溫度度轉化為華氏溫度
double Kelvin(double celsius)
{
return celsius + 273.15;
} //攝氏溫度轉化為開氏溫度
// 露點（點在此溫度時，空氣飽和并產生露珠）
double dewPoint(double celsius, double humidity)
{
double A0= 373.15/(273.15 + celsius);
double SUM = -7.90298 * (A0-1);
SUM += 5.02808 * log10(A0);
SUM += -1.3816e-7 * (pow(10, (11.344*(1-1/A0)))-1) ;
SUM += 8.1328e-3 * (pow(10,(-3.49149*(A0-1)))-1) ;
SUM += log10(1013.246);
double VP = pow(10, SUM-3) * humidity;
double T = log(VP/0.61078); // temp var
return (241.88 * T) / (17.558-T);
}
// 快速計算露點，速度是5倍dewPoint()
// 參考: http://en.wikipedia.org/wiki/Dew_point
double dewPointFast(double celsius, double humidity)
{
double a = 17.271;
double b = 237.7;
double temp = (a * celsius) / (b + celsius) + log(humidity/100);
double Td = (b * temp) / (a - temp);
return Td;
}
#include <dht11.h>
#include <LiquidCrystal.h>
dht11 DHT11;
const int rs = 12, en = 11, d4 = 5, d5 = 4, d6 = 3, d7 = 2;
LiquidCrystal lcd(rs, en, d4, d5, d6, d7);
#define DHT11PIN 8
void setup()
{
Serial.begin(9600);
Serial.println("DHT11 TEST PROGRAM ");
Serial.print("LIBRARY VERSION: ");
Serial.println(DHT11LIB_VERSION);
Serial.println();
lcd.begin(16,2);
lcd.cursor();
}
void loop()
{
Serial.println("\n");
int chk = DHT11.read(DHT11PIN);
Serial.print("Read sensor: ");
switch (chk)
{
case DHTLIB_OK:
Serial.println("OK");
break;
case DHTLIB_ERROR_CHECKSUM:
Serial.println("Checksum error");
break;
case DHTLIB_ERROR_TIMEOUT:
Serial.println("Time out error");
break;
default:
Serial.println("Unknown error");
break;
}
Serial.print("Humidity (%): ");
Serial.println((float)DHT11.humidity, 2);
Serial.print("Temperature (oC): ");
Serial.println((float)DHT11.temperature, 2);
Serial.print("Temperature (oF): ");
Serial.println(Fahrenheit(DHT11.temperature), 2);
Serial.print("Temperature (K): ");
Serial.println(Kelvin(DHT11.temperature), 2);
Serial.print("Dew Point (oC): ");
Serial.println(dewPoint(DHT11.temperature, DHT11.humidity));
Serial.print("Dew PointFast (oC): ");
Serial.println(dewPointFast(DHT11.temperature, DHT11.humidity));
lcd.setCursor(0,0);
lcd.print("Hum(%):");
lcd.setCursor(10,0);
lcd.print((float)DHT11.humidity,2);
lcd.setCursor(0,1);
lcd.print("Temp(oC):");
lcd.setCursor(10,1);
lcd.print((float)DHT11.temperature,2);
delay(2000);
}

復制代碼

代碼是由DHT11類庫自帶的示例代碼進行修改，增加了LCD顯示的代碼進去。

有網友說DHT11模塊的溫度濕度不是很準確，這個大家可以自己感覺，我對比過覺得還是比較準確的，也有網友說它的響應速度慢，其實這個真的見仁見智，感應器的靈敏度再高也不可能秒變的，反正日常家居溫度溫度檢測是能滿足的。

附件里有兩個文件，一個是DHT11的說明文檔PDF格式，一個是Dht11.zip類庫，要加載到Arduino的庫里才能使用，LCD1602的類庫在Arduino的庫管理里搜索安裝即可

附件下載：