鍵盤是由若干按鈕組成的開關(guān)矩陣，它是單片機(jī)系統(tǒng)中最常用的輸入設(shè)備，用戶能通過(guò)鍵盤向計(jì)算機(jī)輸入指令、地址和數(shù)據(jù)。一般單片機(jī)系統(tǒng)中采和非編碼鍵盤，非編碼鍵盤是由軟件來(lái)識(shí)別鍵盤上的閉合鍵，它具有結(jié)構(gòu)簡(jiǎn)單，使用靈活等特點(diǎn)，因此被廣泛應(yīng)用于單片機(jī)系統(tǒng)。
按鈕開關(guān)的抖動(dòng)問(wèn)題
組成鍵盤的按鈕有觸點(diǎn)式和非觸點(diǎn)式兩種，單片機(jī)中應(yīng)用的一般是由機(jī)械觸點(diǎn)組成的。在下圖中，當(dāng)開
<鍵盤結(jié)構(gòu)圖>
|
圖1 |
圖2 |
關(guān)S未被按下時(shí)，P1。0輸入為高電平，S閉合后，P1。0輸入為低電平。由于按鈕是機(jī)械觸點(diǎn)，當(dāng)機(jī)械觸點(diǎn)斷開、閉合時(shí)，會(huì)有抖動(dòng)動(dòng)，P1。0輸入端的波形如圖2所示。這種抖動(dòng)對(duì)于人來(lái)說(shuō)是感覺(jué)不到的，但對(duì)計(jì)算機(jī)來(lái)說(shuō)，則是完全能感應(yīng)到的，因?yàn)橛?jì)算機(jī)處理的速度是在微秒級(jí)，而機(jī)械抖動(dòng)的時(shí)間至少是毫秒級(jí)，對(duì)計(jì)算機(jī)而言，這已是一個(gè)“漫長(zhǎng)”的時(shí)間了。前面我們講到中斷時(shí)曾有個(gè)問(wèn)題，就是說(shuō)按鈕有時(shí)靈，有時(shí)不靈，其實(shí)就是這個(gè)原因，你只按了一次按鈕，可是計(jì)算機(jī)卻已執(zhí)行了多次中斷的過(guò)程，如果執(zhí)行的次數(shù)正好是奇數(shù)次，那么結(jié)果正如你所料，如果執(zhí)行的次數(shù)是偶數(shù)次，那就不對(duì)了。
為使CPU能正確地讀出P1口的狀態(tài)，對(duì)每一次按鈕只作一次響應(yīng)，就必須考慮如何去除抖動(dòng)，常用的去抖動(dòng)的辦法有兩種：硬件辦法和軟件辦法。單片機(jī)中常用軟件法，因此，對(duì)于硬件辦法我們不介紹。軟件法其實(shí)很簡(jiǎn)單，就是在單片機(jī)獲得P1。0口為低的信息后，不是立即認(rèn)定S1已被按下，而是延時(shí)10毫秒或更長(zhǎng)一些時(shí)間后再次檢測(cè)P1。0口，如果仍為低，說(shuō)明S1的確按下了，這實(shí)際上是避開了按鈕按下時(shí)的抖動(dòng)時(shí)間。而在檢測(cè)到按鈕釋放后（P1。0為高）再延時(shí)5-10個(gè)毫秒，消除后沿的抖動(dòng)，然后再對(duì)鍵值處理。不過(guò)一般情況下，我們常常不對(duì)按鈕釋放的后沿進(jìn)行處理，實(shí)踐證明，也能滿足一定的要求。當(dāng)然，實(shí)際應(yīng)用中，對(duì)按鈕的要求也是千差萬(wàn)別，要根據(jù)不一樣的需要來(lái)編制處理程序，但以上是消除鍵抖動(dòng)的原則。
鍵盤與單片機(jī)的連接
|
圖3 |
圖4 |
1、通過(guò)1/0口連接。將每個(gè)按鈕的一端接到單片機(jī)的I/O口，另一端接地，這是最簡(jiǎn)單的辦法，如圖3所示是實(shí)驗(yàn)板上按鈕的接法，四個(gè)按鈕分別接到P3.2 、P3.3、P3.4和P3.5。對(duì)于這種鍵各程序能采用持續(xù)查詢的辦法，功能就是：檢測(cè)是否有鍵閉合，如有鍵閉合，則去除鍵抖動(dòng)，判斷鍵號(hào)并轉(zhuǎn)入對(duì)應(yīng)的鍵處理。下面給出一個(gè)例程。其功能很簡(jiǎn)單，四個(gè)鍵定義如下：
P3.2：開始，按此鍵則燈開始流動(dòng)（由上而下）
P3.3：停止，按此鍵則停止流動(dòng)，所有燈為暗
P3.4：上，按此鍵則燈由上向下流動(dòng)
P3.5：下，按此鍵則燈由下向上流動(dòng)
UpDown EQU 00H ;上下行標(biāo)志
StartEnd EQU 01H ;起動(dòng)及停止標(biāo)志
LAMPCODE EQU 21H ;存放流動(dòng)的數(shù)據(jù)代碼
ORG 0000H
AJMP MAIN
ORG 30H
MAIN:
MOV SP,#5FH
MOV P1,#0FFH
CLR UpDown ;啟動(dòng)時(shí)處于向上的狀態(tài)
CLR StartEnd ;啟動(dòng)時(shí)處于停止?fàn)顟B(tài)
MOV LAMPCODE,#0FEH ;單燈流動(dòng)的代碼
LOOP:
ACALL KEY ;調(diào)用鍵盤程序
JNB F0,LNEXT ;如果無(wú)鍵按下，則繼續(xù)
ACALL KEYPROC ;不然調(diào)用鍵盤處理程序
LNEXT:
ACALL LAMP ;調(diào)用燈顯示程序
AJMP LOOP ;反復(fù)循環(huán)，主程序到此結(jié)束
DELAY:
MOV R7,#100
D1: MOV R6,#100
DJNZ R6,$
DJNZ R7,D1
RET
;----------------------------------------延時(shí)程序，鍵盤處理中調(diào)用
KEYPROC:
MOV A,B ;從B寄存器中獲取鍵值
JB ACC.2,KeyStart ;分析鍵的代碼，某位被按下，則該位為1（因?yàn)樵阪I盤程序中已取反）
JB ACC.3,KeyOver
JB ACC.4,KeyUp
JB ACC.5,KeyDown
AJMP KEY_RET
KeyStart:
SETB StartEnd ;第一個(gè)鍵按下后的處理
AJMP KEY_RET
KeyOver:
CLR StartEnd ;第二個(gè)鍵按下后的處理
AJMP KEY_RET
KeyUp: SETB UpDown ;第三個(gè)鍵按下后的處理
AJMP KEY_RET
KeyDown:
CLR UpDown ;第四個(gè)鍵按下后的處理
KEY_RET:RET
KEY:
CLR F0 ;清F0，表示無(wú)鍵按下。
ORL P3,#00111100B ;將P3口的接有鍵的四位置1
MOV A,P3 ;取P3的值
ORL A,#11000011B ;將其余4位置1
CPL A ;取反
JZ K_RET ;如果為0則一定無(wú)鍵按下
ACALL DELAY ;不然延時(shí)去鍵抖
ORL P3,#00111100B
MOV A,P3
ORL A,#11000011B
CPL A
JZ K_RET
MOV B,A ;確實(shí)有鍵按下，將鍵值存入B中
SETB F0 ;設(shè)置有鍵按下的標(biāo)志
K_RET:
ORL P3,#00111100B ;此處循環(huán)等待鍵的釋放
MOV A,P3
ORL A,#11000011B
CPL A
JZ K_RET1 ;直到讀取的數(shù)據(jù)取反后為0說(shuō)明鍵釋放了，才從鍵盤處理程序中返回
AJMP K_RET
K_RET1:
RET
D500MS: ;流水燈的延遲時(shí)間
PUSH PSW
SETB RS0
MOV R7,#200
D51: MOV R6,#250
D52: NOP
NOP
NOP
NOP
DJNZ R6,D52
DJNZ R7,D51
POP PSW
RET
LAMP:
JB StartEnd,LampStart ;如果StartEnd=1，則啟動(dòng)
MOV P1,#0FFH
AJMP LAMPRET ;不然關(guān)閉所有顯示，返回
LampStart:
JB UpDown,LAMPUP ;如果UpDown=1，則向上流動(dòng)
MOV A,LAMPCODE
RL A ;實(shí)際就是左移位而已
MOV LAMPCODE,A
MOV P1,A
LCALL D500MS
AJMP LAMPRET
LAMPUP:
MOV A,LAMPCODE
RR A ;向下流動(dòng)實(shí)際就是右移
MOV LAMPCODE,A
MOV P1,A
LCALL D500MS
LAMPRET:
RET
END
以上程序功能很簡(jiǎn)單，但它演示了一個(gè)單片機(jī)鍵盤處理程序的基本思路，程序本身很簡(jiǎn)單，也不很實(shí)用，實(shí)際工作中還會(huì)有好多要考慮的因素，比如主循環(huán)每次都調(diào)用燈的循環(huán)程序，會(huì)造成按鈕反應(yīng)“遲鈍”，而如果一直按著鍵不放，則燈不會(huì)再流動(dòng)，一直要到松開手為止，等等，大家能仔細(xì)考慮一下這些問(wèn)題，再想想有什么好的解決辦法。
2、采用中斷方式：如圖4所示。各個(gè)按鈕都接到一個(gè)與非上，當(dāng)有任何一個(gè)按鈕按下時(shí)，都會(huì)使與門輸出為低電平，從而引起單片機(jī)的中斷，它的好處是不用在主程序中持續(xù)地循環(huán)查詢，如果有鍵按下，單片機(jī)再去做對(duì)應(yīng)的處理