設計思路：用定時器中斷產生最小時間單位T0，每m個T0組成一個子周期T10，其中前n個T0為LED導通時間，即Ton=n*T0,則Toff=(m-n)*T0
;每X個T10組成一個母周期T20，其中前y個T10為有效控制時間，后續的（x-y)個T10令LED熄滅或者子周期占空比調至最小。
;適當調節n/m和x/y的比例使顯示效果達到最佳。
;以下是剛剛調試通過的小段程序，顯示效果良好。
;實驗過程本人有一種推測，不知是否成立:
;子周期的最小占空比的寬度應大于LED的點亮時間，即點亮LED的時間寬度n/m*T0應足夠產生余輝。類似于動態數碼管對點亮時間的要求。
;母周期的寬度應小于1/50s，提高刷新頻率以令肉眼察覺不出閃爍。
;未經驗證的推測，可能是錯誤的，請大家接著探討。。。
;芯片: AT89C2051
;晶振：18.9375
;電路描述：輸入5V電源，簡易RC復位，P3.3對地接KEY(減1)，P3.3對地接KEY2(加1)，P3.7接三極管C106驅動LED。LED直徑5mm，紅色。限流電阻471、1/4W.
;功能描述：LED漸亮漸滅。按住KEY可以保持住當前某占空比的亮度（如一開始按住KEY再通電，將看到空度比為1%的亮度）。
;調節子周期和母周期，均可漸亮漸滅。 同時按下“加1”和“減1”按鍵切換選擇調節對象(2004.11.04)
LED BIT P1.1
KEY BIT P3.3
SOV BIT 20H.0 ;子周期顯示完畢標志
BOV BIT 20H.1 ;母周期顯示完畢標志
SSS EQU 30H ;子周期占空寬度調節
T10 EQU 31H ;子周期寬度
AAA EQU 32H ;子周期占空寬度入口
BBB EQU 33H ;母周期占空寬度入口
T20 EQU 34H ;母周期寬度
MMM EQU 35H ;母周期占空寬度調節
A10 EQU 36H ;子周期寬度緩沖
B20 EQU 37H ;母周期寬度緩沖
KEY2 BIT P3.2
COM1 BIT P3.5
COM2 BIT P3.4
COM3 BIT P3.1
COM4 BIT P3.0
NOISE1 EQU 38H
NOISE2 EQU 39H
NOISE3 EQU 3AH
ORG 00H
LJMP MAIN
ORG 0BH
LJMP PWM
PWM:
MOV TH0,#0FFH
MOV TL0,#90H
PUSH ACC
;##
JB BOV,OUTLOW
;**
JB SOV,IFSEND
DEC T10 ;保持計數同步
DJNZ SSS,LRET ;占空參數修正
MOV SSS,AAA ;復原子周期占空參數
MOV A,T10
CJNE A,#0,SCTN ;對占空比為100%時的修正
AJMP T10END
SCTN:
CLR LED
SETB SOV
AJMP LRET
IFSEND:
DJNZ T10,LRET
T10END:
MOV T10,A10 ;復原子周期寬度參數
SETB LED
CLR SOV ;子周期處理完畢
;*
DEC T20
DJNZ MMM,LRET
MOV MMM,BBB
MOV A,T20
CJNE A,#0,MCTN ;對占空比為100%時的修正
AJMP T20END
MCTN:
CLR LED
SETB BOV
AJMP LRET
OUTLOW:
CLR LED ;母周期低電平部分輸出0
DJNZ T10,LRET
MOV T10,A10
DJNZ T20,LRET
T20END:
MOV T20,B20
SETB LED
CLR BOV ;母周期處理完畢
;##
LRET:
POP ACC
RETI
MAIN:
MOV P3,#00001100B
MOV TMOD,#01H
MOV A10,#10 ;子周期寬設置
MOV B20,#20 ;母周期寬設置
MOV T10,A10
MOV T20,B20
MOV AAA,#6 ;子周初始占空寬度設置
MOV BBB,#20 ;母周初始占空寬度設置
MOV SSS,AAA
MOV MMM,BBB
SETB ET0
SETB TR0
SETB EA
SETB LED
MOV 20H,#0;所有標志位清零
MOV R0,#250
MOV R1,#2 ;每隔0.07*250*2ms調節一次亮度
FREE: ;KEY BB
MOV PCON,#1
CHANGE2:
JB KEY,CHOU1
JB KEY2,CHOU1
DJNZ NOISE1,FREE
JNB KEY,$
JNB KEY2,$
AJMP FREE3
CHOU1:
MOV NOISE1,#0
DOWN1:
JB KEY,UP1
DJNZ NOISE2,FREE
DJNZ BBB,NEXT ;減1修正
MOV BBB,#1
NEXT:
JB KEY,FREE ;操作完成后待松鍵再退出
JNB KEY2,FREE
SJMP NEXT
UP1:
MOV NOISE2,#0
IFUP:
JB KEY2,LCRNOS
DJNZ NOISE3,FREE
INC BBB ;加1修正
MOV A,BBB
CJNE A,#21,NEXT2
MOV BBB,#20
NEXT2:
JB KEY2,FREE ;操作完成后待松鍵再退出
JNB KEY,FREE
SJMP NEXT2
LCRNOS:
MOV NOISE3,#0
AJMP FREE ;KEY B
FREE3: ;KEY AA
MOV PCON,#1
CHANGE1:
JB KEY,CHOU2
JB KEY2,CHOU2
DJNZ NOISE1,FREE3
JNB KEY,$
JNB KEY2,$
AJMP FREE
CHOU2:
MOV NOISE1,#0
DOWN2:
JB KEY,UP2
DJNZ NOISE2,FREE3
DJNZ AAA,NEXT3 ;減1修正
MOV AAA,#1
NEXT3:
JB KEY,FREE3 ;操作完成后待松鍵再退出
JNB KEY2,FREE3
SJMP NEXT3
UP2:
MOV NOISE2,#0
IFUP2:
JB KEY2,LCRNOS2
DJNZ NOISE3,FREE3
INC AAA ;加1修正
MOV A,AAA
CJNE A,#11,NEXT4
MOV AAA,#10
NEXT4:
JB KEY2,FREE3 ;操作完成后待松鍵再退出
JNB KEY,FREE3
SJMP NEXT4
LCRNOS2:
MOV NOISE3,#0
AJMP FREE3 ;KEY A
END